flake.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

{
  description = "Jokler points website";
  inputs = {
    nixpkgs.url = "nixpkgs/nixos-unstable";
    fenix = {
      url = "github:nix-community/fenix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = {
    self,
    nixpkgs,
    fenix,
  }: let
    supportedSystems = ["x86_64-linux"];
    forEachSystem = nixpkgs.lib.genAttrs supportedSystems;
    overlayList = [self.overlays.default];
    pkgsBySystem = forEachSystem (
      system:
        import nixpkgs {
          inherit system;
          overlays = overlayList;
        }
    );
  in {
    overlays.default = final: prev: {joklerpoint = final.callPackage ./package.nix {};};

    packages = forEachSystem (system: {
      joklerpoint = let
        inherit (fenix.packages.${system}.minimal) toolchain;
      in
        pkgsBySystem.${system}.callPackage ./package.nix {
          rustPlatform = pkgsBySystem.${system}.makeRustPlatform {
            cargo = toolchain;
            rustc = toolchain;
          };
        };
      default = self.packages.${system}.joklerpoint;
    });

    devShells = forEachSystem (system: {
      default = pkgsBySystem.${system}.callPackage ./shell.nix {};
    });

    nixosModules = import ./nixos-modules {overlays = overlayList;};
  };
}